nvim/init.vim

" Plugins --- {{{

if ! filereadable(system('echo -n "${XDG_CONFIG_HOME:-$HOME/.config}/nvim/autoload/plug.vim"'))
	echo "Downloading junegunn/vim-plug to manage plugins..."
	silent !mkdir -p ${XDG_CONFIG_HOME:-$HOME/.config}/nvim/autoload/
	silent !curl "https://raw.githubusercontent.com/junegunn/vim-plug/master/plug.vim" > ${XDG_CONFIG_HOME:-$HOME/.config}/nvim/autoload/plug.vim
	autocmd VimEnter * PlugInstall
endif

let g:polyglot_disabled = ['markdown']

call plug#begin(stdpath('data') . '/plugged')
Plug 'rafi/awesome-vim-colorschemes'
Plug 'junegunn/fzf', { 'do': { -> fzf#install() } }
Plug 'junegunn/fzf.vim'
Plug 'tpope/vim-surround'
Plug 'tpope/vim-commentary'
Plug 'tpope/vim-unimpaired'
Plug 'jiangmiao/auto-pairs'
Plug 'pangloss/vim-javascript'
Plug 'mattn/emmet-vim'
Plug 'dylanaraps/wal.vim'
Plug 'godlygeek/tabular'
Plug 'plasticboy/vim-markdown'
Plug 'sheerun/vim-polyglot'

"Plug 'phpactor/phpactor', { 'do': 'composer install', 'for': 'php' }
"Plug 'ncm2/ncm2'
"Plug 'roxma/nvim-yarp'

"autocmd BufEnter * call ncm2#enable_for_buffer()
"set completeopt=noinsert,menuone,noselect

"Plug 'phpactor/ncm2-phpactor'
call plug#end()
" }}}

" Basic settings ---- {{{
set nocompatible "Use the latest vim settings/options
syntax enable "Enable syntax highlighting
let mapleader = ',' "The default leader is \, but a comma is much better
let localleader = '\\' "The leader to be used for filetype specific mappings
set number relativenumber "Show relative line numbers
set noerrorbells visualbell t_vb= "Remove the bells
set tabstop=4 "Set how many columns a tab counts for
set shiftwidth=4 "How many columns text is indented when using reindent
set softtabstop=4 "Set columns for tabs in insert mode
set expandtab "Use spaces instead of tabs
set smartindent "Automatically indent code
set ignorecase "Ignores case when searching
set smartcase "Doesn't ignore case when the search includes upper case characters
set backupdir=/tmp// "Store backup files in the /tmp directory
set directory=/tmp// "Store swap files in the /tmp directory
set undodir=/tmp// "Store undo history in the /tmp directory
set undofile "Store the undo history
"set spell "Enable spell checking
set autowriteall "Save the file when switching buffers
set colorcolumn=80,120
"}}}

" Visuals ---- {{{
" colorscheme atom-dark
colorscheme wal
" set t_Co=256 "User 256 colors. This is useful for terminal vim
set guifont=Fira_Code:h17
set guioptions-=e "We don't want GUI tabs

set guioptions-=l
set guioptions-=L
set guioptions-=r
set guioptions-=R
set nowrap "Don't wrap lines around
"Set line number Colour to be same as background
hi LineNr guibg=bg
"Get rid of ugly split borders
hi vertsplit guifg=bg guibg=bg
" }}}

" Split Management --- {{{
set splitbelow
set splitright

"We'll set simpler mappings to switch between splits
nnoremap <C-H> <C-W><C-H>
nnoremap <C-L> <C-W><C-L>
" }}}

" Search --- {{{
set hlsearch
set incsearch

set path+=**
" }}}

" Mappings --- {{{
" Editing files - {{{
"Make it easy to edit the vimrc file
nnoremap <Leader>ev :tabedit $MYVIMRC<cr>
"Source the vimrc file
nnoremap <Leader>es :source $MYVIMRC<cr>
" }}}

"Add simple highlight removal
nnoremap <Leader><space> :nohlsearch<cr>

"Convert tabs to spaces
nnoremap <Leader><Tab> :retab<cr>

"Map movement keys to Escape
inoremap jj <Esc>
inoremap jk <Esc>
inoremap kk <Esc>
inoremap hh <Esc>

"Delete a line in insert mode
inoremap <C-d> <Esc>ddi

"Use semicolon instead of colon for commands
nnoremap ; :

"Append the line with a semicolon
inoremap <Leader>; <Esc>mzA;<Esc>`za
nnoremap <Leader>; mzA;<Esc>`za<Esc>

"Easily navigate items in the quickfix menu
nnoremap <Leader>] :cnext<cr>
nnoremap <Leader>[ :cprevious<cr>

"Indent arrays
nnoremap <Leader>{ mzF[`a<cr><Esc>``%i<cr><Esc>`z
nnoremap <Leader>} mzF[`a<cr><Esc>``%i<cr><Esc>`zvi[:s/,\s*/,\r/g<cr>vi[=<Esc>`z:nohlsearch<cr>

"A command to properly indent json code
command! FormatJSON %!python -m json.tool

" Allow saving of files as sudo
command! W execute 'silent! w !sudo /usr/bin/tee % >/dev/null' <Bar> edit!

" }}}

" Plugins --- {{{
 
" Toggle emmet completion useing <Tab> with <Leader>em
let g:emmet_completion = 0
function ToggleEmmet()
    if g:emmet_completion
        echo "Emmet completion off!"
        let g:user_emmet_expandabbr_key=','
        iunmap <tab>
        let g:emmet_completion = 0
    else
        echo "Emmet completion on!"
        let g:user_emmet_expandabbr_key='<Tab>'
        imap <expr> <tab> emmet#expandAbbrIntelligent("\<tab>")
        let g:emmet_completion = 1
    endif
endfunction
nnoremap <Leader>em :call ToggleEmmet()<cr>

" Conceal markdown text
set conceallevel=3

" }}}

" Moving around --- {{{
"Use capital H and L to move to the start and end of lines
nnoremap H ^
nnoremap L $

"Move a line up or down
nnoremap <C-J> ddp
nnoremap <C-K> ddkP
" }}}

" Operator mappings --- {{{
onoremap in( :<C-u>normal! f(vi(<cr>
onoremap il( :<C-u>normal! F)vi(<cr>
onoremap an( :<C-u>normal! f(va(<cr>
onoremap al( :<C-u>normal! F)va(<cr>
onoremap an{ :<C-u>normal! f{vi(<cr>
onoremap al{ :<C-u>normal! F}vi(<cr>
" }}}

" Abbreviations --- {{{
iabbrev adn and
iabbrev waht what
iabbrev tehn then
iabbrev tihs this
iabbrev teh the
iabbrev Teh The
" }}}

" Auto-Commands --- {{{

"Automatically source the config files on save.
augroup autosourcing
    autocmd!
    autocmd BufWritePost $MYVIMRC source % "Source the vimrc file
augroup END

"Fold vimrc and zshrc files on open
augroup autofolding
    autocmd!
    autocmd BufReadPost $MYVIMRC :setlocal foldlevelstart=0
    autocmd FileType vim setlocal foldmethod=marker
    autocmd BufReadPost zsh :setlocal foldlevelstart=0
    autocmd FileType zsh setlocal foldmethod=marker
augroup END

"Automatically save files
augroup autosaving
    autocmd!
    autocmd FocusLost * silent! wa "Save all files when moving away from the window
augroup END

augroup modes
    autocmd!
    autocmd FocusLost * call feedkeys("\<Esc>") "Go to normal mode when moving away
    autocmd BufNewFile * call feedkeys("i") "Go to insert mode when starting a new file
augroup END

"Recompile suckless software when updating config
augroup suckless
    autocmd BufWritePost ~/.local/src/dwmblocks/config.h !cd ~/.local/src/dwmblocks/; sudo make install && { killall -q dwmblocks;setsid -f dwmblocks }
    autocmd BufWritePost ~/.local/src/dwm/config.h !cd ~/.local/src/dwm/; sudo make clean install
    autocmd BufWritePost ~/.local/src/st/config.h !cd ~/.local/st/dwm/; sudo make clean install

" }}}

" Notes and tips
" - press 'zz' to instantly center the line where the cursor is located.
" - You can increment numbers with <c-a>.
" - To operate on multiple lines use <c-v> to select the lines, <c-i> to go to
"   insert mode, perform edit, press <esc>.
" - Use the command :r to paste the output of a command to the buffer.